Hallo zusammen,
das IntelliLink 900 kann die Cover von MP3's anzeigen.
Da das bei mir nicht auf Anhieb geklappt hat, habe ich u.a. mit Hilfe von verschiedenen Infos hier im Forum rausgefunden, dass die Cover ins MP3 eingebettet sein müssen.
Es reicht also nicht, so wie bei einigen anderen Playern (z.B. Sonos) die Cover in einer Datei (z.B. folder.jpg) im jeweiligen Verzeichnis liegen zu haben.
Das Einbetten der Cover in ein MP3 kann man bequem mit Mp3tag erledigen. Aber leider nur für jedes einzelne Album (im schlimmsten Fall sogar nur für jeden einzelnen Song) von Hand. Wenn man nun, so wie ich, etwa 250 Alben hat, fein säuberlich getagged, bis auf die Cover, dann ist das von Hand eine mühselige und zeitraubende Beschäftigung.
Deshalb habe ich mir ein kleines Script (für Windows) geschrieben, das dies zu meiner Zufriedenheit gelöst hat. Und dieses möchte ich mit euch teilen, vielleicht freut sich ja jemand.
Als Randbedingung galt, dass keine Datei unnötig geändert werden sollte. Es gab nämlich schon ein paar Alben, die die Cover im jeweiligen MP3 eingebettet hatten und es durften keine anderen Tags (Interpret, ...) verloren gehen.
Das Script nutzt zwei Tools, die man auf seinem PC haben muss. Für beide Tools ist keine wirkliche Installation erforderlich, sondern es reicht aus, das beim Entwickler des Tools erhältliche ZIP-File auszupacken. Im Script selbst gibt es einen Abschnitt USER CONFIG. Dort sollten die Pfade zu diesen Tools angepasst werden. Und natürlich der Pfad zu den MP3's muss eingetragen werden. Desweiteren können dort noch ein paar weitere Einstellungen gemacht werden, die hoffentlich selbsterklärend sind.
Eine Bitte, wenn jemand das Script nutzt. Macht vorher eine Kopie eurer MP3's. Das Script hat zwar bei mir und einem Kollegen gut funktioniert, aber ob das immer und überall so sein muss, gilt es zu beweisen.
In jedem Fall gilt, dass keine Garantie übernommen wird.
Bei Fragen fragen.
Grüße
Schwarzer Kaffee
hier ein Auszug aus dem Script, ohne die ganzen Debug-Ausgaben, die das Script dann auch etwas schwer lesbar machen - in jedem Fall die Version aus dem beiliegenden Zip File nutzen!!!!
File setAlbumArt.bat:
rem
rem setAlbumArt.bat
rem write album cover to mp3 file
rem
rem Integrates album cover from a file "folder.jpg" into mp3 files in same directory.
rem If there is no folder.jpg or there is already an album cover integrated in mp3 file
rem then the mp3 file stays untouched. ID3v1 tags get copied to ID3v2 tags if necessary.
rem An simulation mode is available. Set to ON script runs, but does not change any file.
rem
rem You should have a structure like this:
rem
rem c:\
rem |- mp3path <--- see USER CONFIG for definition
rem |- interpret1
rem | |- album1
rem | | |- song1a.mp3
rem | | |- song1b.mp3
rem | | |- folder.jpg <--- see USER CONFIG for definition
rem | |- album2
rem | |- song2a.mp3
rem | |- song2b.mp3
rem | |- folder.jpg <--- see USER CONFIG for definition
rem |- interpret2
rem |- album3
rem |- song3a.mp3
rem |- folder.jpg <--- see USER CONFIG for definition
rem
rem Usage: setAlbumArt
rem
rem OS: Microsoft Windows
rem
rem Required: IDTE is needed for integrating the album cover to the mp3 files.
rem Use a portable version from
rem https://sourceforge.net/projects/idteid3tagedito/
rem In fact just the IDTE.exe from the /bin directory is needed.
rem Note the /bin-directory, there is another IDTE.exe in root-directory
rem which is the GUI variant and will not work for this purpose.
rem
rem ID3 is needed to convert tags from id3v1 to id3v2
rem https://squell.github.io/id3/
rem
rem SVN: $Revision: 1217 $
rem $Date: 2017-09-13 13:59:46 +0200 (Mi, 13 Sep 2017) $
rem
rem License: This work is licensed under a
rem Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License
rem see https://creativecommons.org/licenses/by-nc-sa/4.0/
rem
rem Author: Schwarzer Kaffee (from www.mokka-forum.de)
rem
rem ===========================================================================
cls
rem ---------------------------------------------------------------------------
rem START USER CONFIG ---------------------------------------------------------
rem ---------------------------------------------------------------------------
rem local variables set to your environment
rem path to mp3's - you have to quote, even if there are no blanks in path
set MP3PATH="c:\daten\audiodata-test"
rem path to IDTE.exe - you have to quote, even if there are no blanks in path
set IDTEBIN="C:\bin\IDTE-Portable v2.8\IDTE-ID3-Tag-Editor\Bin\IDTE.exe"
rem path to IDTE.exe - you have to quote, even if there are no blanks in path
set ID3BIN="C:\bin\id3\id3.exe"
rem name of your files with the album cover
rem don't quote here :-)
set COVERFILENAME=folder.jpg
rem type of your album cover: JPG|PNG
set COVERTYPE=JPG
rem name for logfile
set LOGFILE=logfile.log
rem name for temp file
set ID3V2TMP=id3v2.tmp
rem __SIMULATION=ON|OFF
set __SIMULATION=OFF
rem __DEBUG=0|1|2 0=off, 1=some debug messages, 2=all debug messages
set __DEBUG=2
rem ---------------------------------------------------------------------------
rem END USER CONFIG -----------------------------------------------------------
rem ---------------------------------------------------------------------------
rem START SCRIPT CONFIG - DO NOT EDIT WITHOUT ANY NEEDS -----------------------
set SVNREM=$Date: 2017-09-13 13:59:46 +0200 (Mi, 13 Sep 2017) $
rem filename's for album export of IDTE
set ALBUMARTJPG=AlbumArt.jpg
set ALBUMARTPNG=AlbumArt.png
set METADATANOTFOUND="Metadata: none found"
rem MP3PATH without quotes and blanks
for /f "delims=" %%i in (%MP3PATH%) do set "MP3PATH=%%~i"
rem IDTEBIN without quotes and blanks
for /f "delims=" %%i in (%IDTEBIN%) do set "IDTEBIN=%%~i"
rem ID3BIN without quotes and blanks
for /f "delims=" %%i in (%ID3BIN%) do set "ID3BIN=%%~i"
rem write logfile to %MP3PATH%
set LOGFILE="%MP3PATH%\%LOGFILE%"
rem END SCRIPT CONFIG - DO NOT EDIT WITHOUT ANY NEEDS -------------------------
rem write script info to logfile
rem let's check existence of some files
if not exist "%MP3PATH%" goto :END
if not exist "%IDTEBIN%" goto :END
if not exist "%ID3BIN%" goto :END
rem get path to IDTE; necessary because IDTE exports every cover to its own directory
for %%k in ("%IDTEBIN%") do set IDTEPATH=%%~dpk
rem loop over all mp3 files in
for /R "%MP3PATH%" %%I in ("*.mp3") do (
if exist "%IDTEPATH%\%ALBUMARTJPG%" del "%IDTEPATH%\%ALBUMARTJPG%"
if exist "%IDTEPATH%\%ALBUMARTPNG%" del "%IDTEPATH%\%ALBUMARTPNG%"
rem check if there's already a cover integrated in mp3 - read it and check if file available
"%IDTEBIN%" IDTE_GET_INFO 2 "%%I"
rem check if there's cover a cover within the source directory
rem check if there is already an id3v2 header in mp3,
rem if not we have to copy the id3v1 tags to id3v2 tags
rem but we will do that only if we will integrate a cover in the next step
rem so we have to check that before
if not exist "%IDTEPATH%\%ALBUMARTJPG%" if not exist "%IDTEPATH%\%ALBUMARTPNG%" if exist "%%~dpI\%COVERFILENAME%" (
"%ID3BIN%" -2 "%%I" >%ID3V2TMP%
for /f "delims=" %%i in (%ID3V2TMP%) do (
if %__SIMULATION% == OFF if "%%i"==%METADATANOTFOUND% "%ID3BIN%" -1 -2 -u "%%I"
)
if exist %ID3V2TMP% del %ID3V2TMP%
)
rem ok, we have all information available; let's see if we will write a cover to mp3 - maybe or maybe not
rem here just for logfile
rem here that's the real command, but we will go over it, if we're in simulation mode
if %__SIMULATION% == OFF if not exist "%IDTEPATH%\%ALBUMARTJPG%" if not exist "%IDTEPATH%\%ALBUMARTPNG%" if exist "%%~dpI\%COVERFILENAME%" "%IDTEBIN%" IDTE_PIC_WRITE "%%I" "%%~dpI\%COVERFILENAME%" %COVERTYPE%
)
:END
